---
title: "Avatar"
description: "Profile images with initials, status badges, overlapping groups and an account menu."
---

# Avatar

Profile images with initials, status badges, overlapping groups and an account menu.

## Installation

Install the shared package once in your Exact app. This version is a beta.

```sh
bun add --exact @rightui/ui@0.4.0-beta.4
```

Or choose another package manager:

```sh
npm install --save-exact @rightui/ui@0.4.0-beta.4
pnpm add --save-exact @rightui/ui@0.4.0-beta.4
yarn add --exact @rightui/ui@0.4.0-beta.4
```

Exact compilation uses Bun 1.4.2. Register Geist and Newsreader, declare the font marker and add the root provider using [Installation](/docs/installation).

### Manual source setup

Install an editable copy of the complete package:

```sh
mkdir -p vendor/rightui vendor/rightui-ui
npm pack @rightui/ui@0.4.0-beta.4 --pack-destination vendor/rightui
tar -xzf ./vendor/rightui/rightui-ui-0.4.0-beta.4.tgz -C vendor/rightui-ui --strip-components=1
bun add file:./vendor/rightui-ui
```

Keep package.json, the Contract files, ui.tamber, assets and licenses together.

### Import

```contract
use Avatar, AvatarFrame, AvatarBadge, AvatarStatus, AvatarGroup, AvatarGroupItem, AvatarGroupItemDirected, AvatarGroupCount, AvatarGroupOverflow, AvatarGroupOverflowDirected, AvatarMenu from "@rightui/ui"
```

## Usage

Use AvatarFrame for an image and fallback, then compose AvatarStatus or AvatarBadge inside it. Group profiles with AvatarGroup and AvatarGroupItem. Sizes are sm, default and lg. AvatarMenu adds a keyboard-accessible account menu.

## Example

```contract
use FontWeights from "@rightui/ui"
use uiFontFamily, AvatarFrame, AvatarBadge, AvatarStatus, AvatarGroup, AvatarGroupItemDirected, AvatarGroupCount, AvatarGroupOverflowDirected, AvatarMenu, MenuEntry, Direction from "@rightui/ui"

fn avatarName(person: number): string = person == 0 ? "@ccheever" : person == 1 ? "@maxleiter" : "@evilrabbit"
fn avatarSource(person: number): string = person == 0 ? "assets/avatars/user-blue.png" : person == 1 ? "assets/avatars/user-violet.png" : "assets/avatars/user-green.png"
fn avatarInitials(person: number): string = person == 0 ? "CC" : person == 1 ? "ML" : "ER"

component Demo
  props
    width: number
    reduced: bool
  view
    column gap="ui.space-32" min-width=0
      Overview(width=width, reduced=reduced)
      Examples(width=width, reduced=reduced)

component Overview
  props
    width: number
    reduced: bool
  view
    AvatarOverview(id="avatar-overview", compact=(width < 600), direction="ltr")

component Examples
  props
    width: number
    reduced: bool
  inject
    uiFont: string
  state selected = ""
  action choose(value: string)
    selected = value
  view
    column gap="ui.space-32" min-width=0 max-width="100%"
      AvatarExample(title="Basic", description="A profile image with a fallback when it cannot load.")
        ProfileAvatar(id="avatar-basic", person=0, size="default")
      AvatarExample(title="Fallback", description="Initials remain visible when no image is supplied.")
        AvatarFrame(id="avatar-fallback", name="Charlie Cheever", src="", fallback="CC", size="default")
      AvatarExample(title="Badge", description="A small status indicator with an accessible label.")
        AvatarFrame(id="avatar-status", name="@ccheever", src=avatarSource(0), fallback="CC", size="default")
          AvatarStatus(id="avatar-status-online", label="Available", size="default", tone="success")
      AvatarExample(title="Badge with Icon", description="Add an icon inside the badge.")
        AvatarFrame(id="avatar-icon", name="@ccheever", src=avatarSource(0), fallback="CC", size="default")
          AvatarBadge(id="avatar-icon-badge", label="Add member", size="default")
            AvatarPlus(small=true)
      AvatarExample(title="Avatar Group", description="Stack related profiles with a contrasting outline.")
        ProfileGroup(id="avatar-group", size="default", overflow="none", direction="ltr")
      AvatarExample(title="Avatar Group Count", description="Show how many additional people belong to the group.")
        ProfileGroup(id="avatar-group-count", size="default", overflow="count", direction="ltr")
      AvatarExample(title="Avatar Group with Icon", description="Use custom content in the overflow indicator.")
        ProfileGroup(id="avatar-group-icon", size="default", overflow="icon", direction="ltr")
      AvatarExample(title="Sizes", description="Small, default and large avatars share the same image and fallback behavior.")
        row gap="ui.space-8" align-items="center" flex-wrap="wrap"
          ProfileAvatar(id="avatar-sm", person=0, size="sm")
          ProfileAvatar(id="avatar-default", person=0, size="default")
          ProfileAvatar(id="avatar-lg", person=0, size="lg")
      AvatarExample(title="Dropdown", description="Open the account menu with a click or the keyboard.")
        column align-items="center" gap="ui.space-12"
          AvatarMenu(id="avatar-menu", name="@ccheever", src=avatarSource(0), fallback="CC", entries=[MenuEntry(id="profile", label="Profile", shortcut="", disabled=false, destructive=false), MenuEntry(id="billing", label="Billing", shortcut="", disabled=false, destructive=false), MenuEntry(id="settings", label="Settings", shortcut="", disabled=false, destructive=false), MenuEntry(id="logout", label="Log out", shortcut="", disabled=false, destructive=true)], reduced=reduced, choose=choose)
          text (selected == "" ? "Choose an account action" : "Selected: " + selected) id="avatar-menu-selection" testId="avatar-menu-selection" role="status" font-size="ui.text-xs" color="ui.muted-foreground" font-family=uiFontFamily(uiFont) data-rightui-font="body"
      AvatarExample(title="RTL", description="The same composition in a right-to-left layout.")
        Direction(id="avatar-rtl", direction="rtl")
          AvatarOverview(id="avatar-rtl-overview", compact=(width < 600), direction="rtl")

component AvatarExample
  props
    title: string
    description: string
  inject
    uiWeights: FontWeights
    uiFont: string
  slot
  view
    column gap="ui.space-12" min-width=0
      text title role="heading" aria-level=3 font-size="ui.text-base" font-weight=uiWeights.semibold color="ui.foreground" font-family=uiFontFamily(uiFont) data-rightui-font="body"
      text description font-size="ui.text-sm" line-height="ui.leading-relaxed" color="ui.muted-foreground" font-family=uiFontFamily(uiFont) data-rightui-font="body"
      row min-height="ui.space-80" align-items="center" justify-content="center" gap="ui.space-16" flex-wrap="wrap" padding="ui.space-16" border-width="ui.border-width" border-style="solid" border-color="ui.border" border-radius="ui.panel-radius" min-width=0
        children

component AvatarOverview
  props
    id: string
    compact: bool
    direction: string
  view
    row id=id testId=id min-height="ui.space-80" gap=(compact ? "ui.space-24" : "ui.space-48") align-items="center" justify-content="center" flex-wrap="wrap" min-width=0
      ProfileAvatar(id=id + "-profile", person=0, size="default")
      AvatarFrame(id=id + "-status", name="@evilrabbit", src=avatarSource(2), fallback="ER", size="default")
        AvatarStatus(id=id + "-available", label="Available", size="default", tone="success")
      ProfileGroup(id=id + "-group", size="default", overflow="count", direction=direction)

component ProfileAvatar
  props
    id: string
    person: number
    size: string
  view
    AvatarFrame(id=id, name=avatarName(person), src=avatarSource(person), fallback=avatarInitials(person), size=size)

component ProfileGroup
  props
    id: string
    size: string
    overflow: string
    direction: string
  inject
    uiFont: string
  view
    AvatarGroup(id=id, label="Project team")
      for person in [0, 1, 2] key=person
        AvatarGroupItemDirected(id=id + "-member-" + person.toString(), first=(person == 0), direction=direction)
          ProfileAvatar(id=id + "-profile-" + person.toString(), person=person, size=size)
      if overflow == "count" and direction == "rtl"
        AvatarGroupOverflowDirected(id=id + "-count", label="3 more members", size=size, first=false, direction=direction)
          text "+3" aria-hidden=true font-size="ui.text-sm" color="ui.muted-foreground" font-family=uiFontFamily(uiFont) data-rightui-font="body"
      else if overflow == "count"
        AvatarGroupCount(id=id + "-count", label="3 more members", count=3, size=size, first=false)
      else if overflow == "icon"
        AvatarGroupOverflowDirected(id=id + "-more", label="More members", size=size, first=false, direction=direction)
          AvatarPlus(small=false)

component AvatarPlus
  props
    small: bool
  view
    svg width=(small ? "ui.space-8" : "ui.space-16") height=(small ? "ui.space-8" : "ui.space-16") viewBox="0 0 24 24" fill="none" stroke="currentColor" stroke-width="ui.icon-stroke" stroke-linecap="round" aria-hidden=true
      path d="M12 5v14M5 12h14"

```

## Keyboard

AvatarMenu: Enter, Space or ArrowDown opens the menu; ArrowUp opens at the last enabled item. Arrow keys, Home, End and typing move focus. Enter or Space selects an item. Escape closes and returns focus to the avatar.

## API Reference

| Property | Type |
| --- | --- |
| AvatarMenu.id | string |
| AvatarMenu.name | string |
| AvatarMenu.src | string |
| AvatarMenu.fallback | string |
| AvatarMenu.entries | MenuEntry[] |
| AvatarMenu.reduced | bool |
| AvatarMenu.choose | action |
| AvatarFrame.id | string |
| AvatarFrame.name | string |
| AvatarFrame.src | string |
| AvatarFrame.fallback | string |
| AvatarFrame.size | string |
| AvatarStatus.id | string |
| AvatarStatus.label | string |
| AvatarStatus.size | string |
| AvatarStatus.tone | string |
| AvatarBadge.id | string |
| AvatarBadge.label | string |
| AvatarBadge.size | string |
| AvatarGroup.id | string |
| AvatarGroup.label | string |
| AvatarGroupItemDirected.id | string |
| AvatarGroupItemDirected.first | bool |
| AvatarGroupItemDirected.direction | string |
| AvatarGroupOverflowDirected.id | string |
| AvatarGroupOverflowDirected.label | string |
| AvatarGroupOverflowDirected.size | string |
| AvatarGroupOverflowDirected.first | bool |
| AvatarGroupOverflowDirected.direction | string |
| AvatarGroupItem.id | string |
| AvatarGroupItem.first | bool |
| AvatarGroupOverflow.id | string |
| AvatarGroupOverflow.label | string |
| AvatarGroupOverflow.size | string |
| AvatarGroupOverflow.first | bool |
| AvatarGroupCount.id | string |
| AvatarGroupCount.label | string |
| AvatarGroupCount.count | number |
| AvatarGroupCount.size | string |
| AvatarGroupCount.first | bool |
| Avatar.id | string |
| Avatar.src | string |
| Avatar.name | string |
| Avatar.fallback | string |

## Source

File: packages/ui/composition.contract

```contract
use FontWeights from "./typography-context.contract"
use uiFontFamily from "./typography-context.contract"
// Pass the resolved inset to each part: caller-owned slots retain their caller's providers.
fn cardSpacing(size: string, spacing: string): string = spacing != "" ? spacing : size == "sm" ? "ui.space-12" : "ui.space-24"

component CardFrame
  props
    id: string
  slot
  view
    CardFrameOptions(id=id, size="default", spacing="", imageTop=false, direction="inherit")
      children

component CardFrameOptions
  props
    id: string
    size: string
    spacing: string
    imageTop: bool
    direction: string
  derive inset = cardSpacing(size, spacing)
  slot
  view
    column appearance="none" id=id testId=id direction=direction gap=inset padding-top=(imageTop ? "0px" : inset) padding-bottom=inset min-width="0px" max-width="100%" box-sizing="border-box" overflow=(imageTop ? "hidden" : "visible") border-width="ui.border-width" border-style="solid" border-color="ui.border" border-radius="ui.panel-radius" background-color="ui.surface" color="ui.foreground" box-shadow="ui.shadow-control"
      children

component CardHeader
  props
    id: string
  slot
  view
    CardHeaderOptions(id=id, spacing="", divided=false)
      children

component CardHeaderOptions
  props
    id: string
    spacing: string
    divided: bool
  derive inset = cardSpacing("default", spacing)
  slot
  view
    view appearance="none" id=id testId=id display="grid" grid-template-columns="minmax(0, 1fr) auto" grid-template-rows="auto auto" align-items="start" column-gap="ui.space-8" row-gap="ui.space-8" padding-left=inset padding-right=inset padding-bottom=(divided ? inset : "0px") border-bottom-width=(divided ? "ui.border-width" : "0px") border-bottom-style="solid" border-bottom-color="ui.border" min-width="0px"
      children

component CardTitle
  props
    id: string
    title: string
    level: number
  inject
    uiWeights: FontWeights
    uiFont: string
  view
    text title appearance="none" id=id testId=id grid-column="1" grid-row="1" min-width="0px" font-size="ui.text-base" line-height="ui.leading-solid" font-weight=uiWeights.semibold role="heading" aria-level=level overflow-wrap="break-word" font-family=uiFontFamily(uiFont) data-rightui-font="body"

component CardDescription
  props
    id: string
    description: string
  inject
    uiFont: string
  view
    text description appearance="none" id=id testId=id grid-column="1" grid-row="2" min-width="0px" font-size="ui.text-sm" line-height="ui.leading-normal" color="ui.muted-foreground" overflow-wrap="break-word" font-family=uiFontFamily(uiFont) data-rightui-font="body"

component CardAction
  props
    id: string
  slot
  view
    view appearance="none" id=id testId=id grid-column="2" grid-row="1 / span 2" align-self="start" min-width="0px"
      children

component CardContent
  props
    id: string
  slot
  view
    CardContentOptions(id=id, spacing="", edgeToEdge=false, connectedFooter=false)
      children

component CardContentOptions
  props
    id: string
    spacing: string
    edgeToEdge: bool
    connectedFooter: bool
  derive inset = cardSpacing("default", spacing)
  derive bottom = connectedFooter ? ("calc(" + inset + " * -1)") : "0px"
  slot
  view
    column appearance="none" id=id testId=id padding-left=(edgeToEdge ? "0px" : inset) padding-right=(edgeToEdge ? "0px" : inset) margin-bottom=bottom min-width="0px"
      children

component CardFooter
  props
    id: string
    divided: bool
  slot
  view
    CardFooterOptions(id=id, spacing="", divided=divided)
      children

component CardFooterOptions
  props
    id: string
    spacing: string
    divided: bool
  derive inset = cardSpacing("default", spacing)
  slot
  view
    row appearance="none" id=id testId=id align-items="center" flex-wrap="wrap" gap="ui.space-8" padding-top=(divided ? inset : "0px") padding-left=inset padding-right=inset border-top-width=(divided ? "ui.border-width" : "0px") border-top-style="solid" border-top-color=(divided ? "ui.border" : "transparent") min-width="0px"
      children

fn avatarSize(size: string): string = size == "sm" ? "ui.avatar-sm" : size == "lg" ? "ui.avatar-lg" : "ui.avatar-size"

// Keyed by source in AvatarFrame so changing a failed URL starts a fresh image lifecycle.
component AvatarPicture
  props
    id: string
    name: string
    src: string
    fallback: string
    size: string
  inject
    uiFont: string
  state loaded = false
  state failed = false
  action imageLoaded
    loaded = true
  action imageFailed(message: string)
    failed = true
    loaded = false
  view
    view width="100%" height="100%" position="relative" overflow="hidden" border-radius="ui.avatar-radius" background-color="ui.avatar-background" display="flex" align-items="center" justify-content="center" role="img" aria-label=name
      if not loaded
        text fallback id=(id + "-fallback") testId=(id + "-fallback") aria-hidden=true font-size=(size == "sm" ? "ui.text-xs" : "ui.text-sm") line-height="ui.leading-solid" color="ui.avatar-foreground" font-family=uiFontFamily(uiFont) data-rightui-font="body"
      if src != "" and not failed
        image src id=(id + "-image") testId=(id + "-image") alt="" position="absolute" left=0 top=0 width="100%" height="100%" object-fit="cover" pointer-events="none" load=imageLoaded error=imageFailed
      view aria-hidden=true pointer-events="none" position="absolute" left=0 right=0 top=0 bottom=0 border-radius="ui.avatar-radius" border-width="ui.avatar-border-width" border-style="solid" border-color="ui.avatar-border"

component AvatarFrame
  props
    id: string
    name: string
    src: string
    fallback: string
    size: string
  slot
  view
    view id=id testId=id position="relative" width=avatarSize(size) height=avatarSize(size) flex-shrink=0
      for source in [src] key=source
        AvatarPicture(id=id, name=name, src=source, fallback=fallback, size=size)
      children

component AvatarStatus
  props
    id: string
    label: string
    size: string
    tone: string
  slot
  view
    view id=id testId=id role="img" aria-label=label position="absolute" right="0px" bottom="0px" z-index=10 width=(size == "sm" ? "ui.avatar-badge-sm" : size == "lg" ? "ui.avatar-badge-lg" : "ui.avatar-badge-size") height=(size == "sm" ? "ui.avatar-badge-sm" : size == "lg" ? "ui.avatar-badge-lg" : "ui.avatar-badge-size") border-radius="ui.radius-full" background-color=(tone == "success" ? "ui.success" : tone == "destructive" ? "ui.danger" : "ui.primary") color="ui.primary-foreground" box-shadow="ui.avatar-ring" display="flex" align-items="center" justify-content="center"
      if size != "sm"
        children

component AvatarBadge
  props
    id: string
    label: string
    size: string
  slot
  view
    AvatarStatus(id=id, label=label, size=size, tone="default")
      children

component AvatarGroup
  props
    id: string
    label: string
  slot
  view
    row id=id testId=id role="group" aria-label=label align-items="center" padding="ui.space-2"
      children

component AvatarGroupItemDirected
  props
    id: string
    first: bool
    direction: string
  slot
  view
    view id=id testId=id margin-left=(not first and direction != "rtl" ? "ui.avatar-overlap" : "0px") margin-right=(not first and direction == "rtl" ? "ui.avatar-overlap" : "0px") border-radius="ui.avatar-radius" box-shadow="ui.avatar-ring" flex-shrink=0 position="relative"
      children

component AvatarGroupOverflowDirected
  props
    id: string
    label: string
    size: string
    first: bool
    direction: string
  slot
  view
    view id=id testId=id role="img" aria-label=label margin-left=(not first and direction != "rtl" ? "ui.avatar-overlap" : "0px") margin-right=(not first and direction == "rtl" ? "ui.avatar-overlap" : "0px") width=avatarSize(size) height=avatarSize(size) border-radius="ui.avatar-radius" background-color="ui.avatar-background" color="ui.avatar-foreground" box-shadow="ui.avatar-ring" display="flex" align-items="center" justify-content="center" flex-shrink=0 position="relative"
      children

component AvatarGroupItem
  props
    id: string
    first: bool
  slot
  view
    AvatarGroupItemDirected(id=id, first=first, direction="ltr")
      children

component AvatarGroupOverflow
  props
    id: string
    label: string
    size: string
    first: bool
  slot
  view
    AvatarGroupOverflowDirected(id=id, label=label, size=size, first=first, direction="ltr")
      children

component AvatarGroupCount
  props
    id: string
    label: string
    count: number
    size: string
    first: bool
  inject
    uiFont: string
  view
    AvatarGroupOverflow(id=id, label=label, size=size, first=first)
      text ("+" + max(0, floor(count)).toString()) aria-hidden=true font-size=(size == "sm" ? "ui.text-xs" : "ui.text-sm") line-height="ui.leading-solid" color="ui.avatar-foreground" font-family=uiFontFamily(uiFont) data-rightui-font="body"

component FieldSet
  props
    id: string
    legendId: string
    descriptionId: string
    disabled: bool
  slot
  view
    column id=id testId=id role="group" aria-labelledby=legendId aria-describedby=descriptionId aria-disabled=disabled gap="ui.space-24" min-width="0px"
      children

component FieldLegend
  props
    id: string
    label: string
    variant: string
  inject
    uiWeights: FontWeights
    uiFont: string
  view
    text label id=id testId=id margin-bottom="ui.space-12" font-size=(variant == "label" ? "ui.text-sm" : "ui.text-base") font-weight=uiWeights.medium line-height="ui.leading-normal" color="ui.foreground" font-family=uiFontFamily(uiFont) data-rightui-font="body"

component FieldGroup
  props
    id: string
    nested: bool
  slot
  view
    column id=id testId=id gap=(nested ? "ui.space-16" : "ui.space-28") min-width="0px"
      children

component FieldFrame
  props
    id: string
    labelId: string
    descriptionId: string
    invalid: bool
    orientation: string
  slot
  view
    view id=id testId=id role="group" aria-labelledby=labelId aria-describedby=descriptionId aria-invalid=invalid display="flex" flex-direction=(orientation == "horizontal" ? "row" : "column") align-items=(orientation == "horizontal" ? "center" : "stretch") gap="ui.space-12" min-width="0px" color=(invalid ? "ui.danger" : "ui.foreground")
      children

component FieldContent
  props
    id: string
  slot
  view
    column id=id testId=id flex=1 gap="ui.space-6" min-width="0px" line-height="ui.leading-compact"
      children

component FieldLabel
  props
    id: string
    label: string
    controlId: string
    disabled: bool
  inject
    uiWeights: FontWeights
    uiFont: string
  action activate
    if not disabled
      focus(controlId)
  view
    text label id=id testId=id press=activate appearance="none" background-color="transparent" font-size="ui.text-sm" font-weight=uiWeights.medium line-height="ui.leading-compact" color="ui.foreground" opacity=(disabled ? "ui.opacity-disabled" : 1) font-family=uiFontFamily(uiFont) data-rightui-font="body"
      :hover
        background-color="transparent"
      :active
        background-color="transparent"

component FieldTitle
  props
    id: string
    title: string
    disabled: bool
  inject
    uiWeights: FontWeights
    uiFont: string
  view
    text title id=id testId=id font-size="ui.text-sm" font-weight=uiWeights.medium line-height="ui.leading-compact" color="ui.foreground" opacity=(disabled ? "ui.opacity-disabled" : 1) font-family=uiFontFamily(uiFont) data-rightui-font="body"

component FieldDescription
  props
    id: string
    description: string
  inject
    uiFont: string
  view
    text description id=id testId=id font-size="ui.text-sm" line-height="ui.leading-normal" color="ui.muted-foreground" overflow-wrap="break-word" font-family=uiFontFamily(uiFont) data-rightui-font="body"

component FieldError
  props
    id: string
    messages: string[]
  inject
    uiWeights: FontWeights
    uiFont: string
  derive unique = messages.filter((message, index) => message.trim() != "" and messages.indexOf(message) == index)
  view
    if unique.length > 0
      column id=id testId=id role="alert" gap="ui.space-4" font-size="ui.text-sm" font-weight=uiWeights.regular color="ui.danger"
        if unique.length == 1
          text unique.join("") testId=(id + "-message-0") overflow-wrap="break-word" font-family=uiFontFamily(uiFont) data-rightui-font="body"
        else
          column role="list" gap="ui.space-4" padding-left="ui.space-16"
            for message, i in unique key=message
              text ("• " + message) testId=(id + "-message-" + i.toString()) role="listitem" overflow-wrap="break-word" font-family=uiFontFamily(uiFont) data-rightui-font="body"

component FieldSeparator
  props
    id: string
    label: string
  inject
    uiFont: string
  view
    row id=id testId=id role="separator" aria-orientation="horizontal" aria-label=label align-items="center" min-height="ui.space-20" margin="ui.space-negative-8 0px"
      view height="ui.border-width" background-color="ui.border" flex=1 aria-hidden=true
      if label != ""
        text label padding="0px ui.space-8" font-size="ui.text-sm" line-height="ui.leading-normal" color="ui.muted-foreground" font-family=uiFontFamily(uiFont) data-rightui-font="body"
        view height="ui.border-width" background-color="ui.border" flex=1 aria-hidden=true

component ButtonGroupText
  props
    id: string
  slot
  inject
    uiWeights: FontWeights
  view
    row id=id testId=id align-items="center" gap="ui.space-8" min-height="ui.space-36" padding="0px ui.space-16" border-width="ui.border-width" border-style="solid" border-color="ui.border" border-radius="ui.radius-control" background-color="ui.muted" font-size="ui.text-sm" font-weight=uiWeights.medium color="ui.foreground" box-shadow="ui.shadow-control"
      children

component ButtonGroupSeparator
  props
    vertical: bool
  view
    view role="separator" aria-orientation=(vertical ? "vertical" : "horizontal") align-self="stretch" flex-shrink=0 width=(vertical ? "ui.space-1" : "100%") height=(vertical ? "auto" : "ui.space-1") background-color="ui.input"

component KbdGroup
  props
    id: string
    label: string
  slot
  view
    row id=id testId=id role="group" aria-label=label align-items="center" gap="ui.space-4"
      children

```
