---
title: "Menubar"
description: "Menubar with accessible presentation and local state."
---

# Menubar

Menubar with accessible presentation and local state.

## Installation

Install the shared package once in your Exact app. This version is a beta.

```sh
bun add --exact @rightui/ui@0.4.0-beta.4
```

Or choose another package manager:

```sh
npm install --save-exact @rightui/ui@0.4.0-beta.4
pnpm add --save-exact @rightui/ui@0.4.0-beta.4
yarn add --exact @rightui/ui@0.4.0-beta.4
```

Exact compilation uses Bun 1.4.2. Register Geist and Newsreader, declare the font marker and add the root provider using [Installation](/docs/installation).

### Manual source setup

Install an editable copy of the complete package:

```sh
mkdir -p vendor/rightui vendor/rightui-ui
npm pack @rightui/ui@0.4.0-beta.4 --pack-destination vendor/rightui
tar -xzf ./vendor/rightui/rightui-ui-0.4.0-beta.4.tgz -C vendor/rightui-ui --strip-components=1
bun add file:./vendor/rightui-ui
```

Keep package.json, the Contract files, ui.tamber, assets and licenses together.

### Import

```contract
use MenubarGroup, Menubar, MenubarAdvanced from "@rightui/ui"
```

## Usage

Import MenubarGroup, Menubar from @rightui/ui. Store its value in state and update it through the provided action callback.

## Example

```contract
use MenubarAdvanced, AdvancedMenuEntry, AdvancedMenuGroup, AdvancedMenuSelection from "@rightui/ui"

component Demo
  props
    width: number
    reduced: bool
  derive narrow = width < 600
  state checks: string[] = ["status", "bookmarks"]
  state radios: AdvancedMenuSelection[] = [AdvancedMenuSelection(group="position", value="bottom"), AdvancedMenuSelection(group="person", value="pedro"), AdvancedMenuSelection(group="zoom", value="100")]
  action choose(value: string)
    chosen = value
  action check(id: string, value: bool)
    checks = value ? checks.filter(item => item != id).concat([id]) : checks.filter(item => item != id)
  action radio(group: string, value: string)
    radios = radios.filter(item => item.group != group).concat([AdvancedMenuSelection(group=group, value=value)])
  state chosen = "No action"
  view
    column gap="ui.space-16" min-width=0 max-width="100%"
      MenubarAdvanced(id="parity-menubar", label="Application menu", menus=[AdvancedMenuGroup(id="file", label="File", entries=[AdvancedMenuEntry(id="new-tab", parent="", label="New Tab", kind="item", shortcut="⌘T", disabled=false, group="", value=""), AdvancedMenuEntry(id="new-window", parent="", label="New Window", kind="item", shortcut="⌘N", disabled=false, group="", value=""), AdvancedMenuEntry(id="incognito", parent="", label="New Incognito Window", kind="item", shortcut="", disabled=true, group="", value=""), AdvancedMenuEntry(id="file-separator", parent="", label="", kind="separator", shortcut="", disabled=false, group="", value=""), AdvancedMenuEntry(id="share", parent="", label="Share", kind="submenu", shortcut="", disabled=false, group="", value=""), AdvancedMenuEntry(id="share-email", parent="share", label="Email link", kind="item", shortcut="", disabled=false, group="", value=""), AdvancedMenuEntry(id="share-messages", parent="share", label="Messages", kind="item", shortcut="", disabled=false, group="", value=""), AdvancedMenuEntry(id="share-notes", parent="share", label="Notes", kind="item", shortcut="", disabled=false, group="", value=""), AdvancedMenuEntry(id="print-separator", parent="", label="", kind="separator", shortcut="", disabled=false, group="", value=""), AdvancedMenuEntry(id="print", parent="", label="Print…", kind="item", shortcut="⌘P", disabled=false, group="", value="")]), AdvancedMenuGroup(id="edit", label="Edit", entries=[AdvancedMenuEntry(id="undo", parent="", label="Undo", kind="item", shortcut="⌘Z", disabled=false, group="", value=""), AdvancedMenuEntry(id="redo", parent="", label="Redo", kind="item", shortcut="⇧⌘Z", disabled=false, group="", value=""), AdvancedMenuEntry(id="edit-separator", parent="", label="", kind="separator", shortcut="", disabled=false, group="", value=""), AdvancedMenuEntry(id="find", parent="", label="Find", kind="submenu", shortcut="", disabled=false, group="", value=""), AdvancedMenuEntry(id="find-web", parent="find", label="Search the web", kind="item", shortcut="", disabled=false, group="", value=""), AdvancedMenuEntry(id="find-next", parent="find", label="Find Next", kind="item", shortcut="", disabled=false, group="", value=""), AdvancedMenuEntry(id="find-previous", parent="find", label="Find Previous", kind="item", shortcut="", disabled=false, group="", value="")]), AdvancedMenuGroup(id="view", label="View", entries=[AdvancedMenuEntry(id="bookmarks", parent="", label="Always Show Bookmarks Bar", kind="checkbox", shortcut="", disabled=false, group="", value=""), AdvancedMenuEntry(id="status", parent="", label="Always Show Status Bar", kind="checkbox", shortcut="", disabled=false, group="", value=""), AdvancedMenuEntry(id="view-separator", parent="", label="", kind="separator", shortcut="", disabled=false, group="", value=""), AdvancedMenuEntry(id="zoom", parent="", label="Zoom", kind="submenu", shortcut="", disabled=false, group="", value=""), AdvancedMenuEntry(id="zoom-group", parent="zoom", label="Zoom level", kind="group", shortcut="", disabled=false, group="", value=""), AdvancedMenuEntry(id="zoom-100", parent="zoom-group", label="100%", kind="radio", shortcut="", disabled=false, group="zoom", value="100"), AdvancedMenuEntry(id="zoom-125", parent="zoom-group", label="125%", kind="radio", shortcut="", disabled=false, group="zoom", value="125"), AdvancedMenuEntry(id="zoom-150", parent="zoom-group", label="150%", kind="radio", shortcut="", disabled=false, group="zoom", value="150")]), AdvancedMenuGroup(id="variation-person", label="People", entries=[AdvancedMenuEntry(id="variation-person-pedro", parent="", label="Pedro", kind="radio", shortcut="", disabled=false, group="person", value="pedro"),AdvancedMenuEntry(id="variation-person-alex", parent="", label="Alex", kind="radio", shortcut="", disabled=false, group="person", value="alex")])], checks=checks, radios=radios, reduced=reduced, choose=choose, check=check, radio=radio)

```

## API Reference

| Property | Type |
| --- | --- |
| MenubarAdvanced.id | string |
| MenubarAdvanced.label | string |
| MenubarAdvanced.menus | AdvancedMenuGroup[] |
| MenubarAdvanced.checks | string[] |
| MenubarAdvanced.radios | AdvancedMenuSelection[] |
| MenubarAdvanced.reduced | bool |
| MenubarAdvanced.choose | action |
| MenubarAdvanced.check | action |
| MenubarAdvanced.radio | action |
| Menubar.id | string |
| Menubar.groups | MenubarGroup[] |
| Menubar.reduced | bool |
| Menubar.choose | action |

## Source

File: packages/ui/menubar.contract

```contract
use FontWeights from "./typography-context.contract"
use uiFontFamily from "./typography-context.contract"
use Control from "./styles.contract"
use DropdownMenuPanel, MenuEntry from "./menu.contract"
shape MenubarGroup
  id: string
  label: string
  entries: MenuEntry[]
component Menubar
  props
    id: string
    groups: MenubarGroup[]
    reduced: bool
    choose: action
  inject
    uiWeights: FontWeights
    uiFont: string
  state active = 0
  state expanded = false
  state opening = 0
  derive prefix = match groups.at(active) { case some(group) => id + "-" + group.id, case none => id }
  derive current = match groups.at(active) { case some(group) => group.entries, case none => [] }
  derive currentLabel = match groups.at(active) { case some(group) => group.label, case none => "" }
  state anchorX = 0
  state anchorY = 0
  state anchorHeight = 0
  state anchorWidth = 0
  state switching = false
  state hoverSwitched = false
  action measureAnchor(index: number)
    match groups.at(index)
      case some(group)
        let trigger = frame(id + "-" + group.id)
        let container = frame(id)
        if not trigger.unavailable and not container.unavailable and not trigger.provisional and not container.provisional
          anchorX = trigger.x - container.x
          anchorY = trigger.y - container.y
          anchorHeight = trigger.height
          anchorWidth = trigger.width
      case none
        anchorWidth = 0
  action resized(width: number, height: number)
    if expanded
      measureAnchor(active)
  action open(index: number, lastItem: bool)
    hoverSwitched = false
    match groups.at(index)
      case some(group)
        measureAnchor(index)
        switching = expanded
        if not expanded
          opening = opening + 1
          showPopover(id + "-menu", source=id + "-anchor")
        active = index
        expanded = true
        let enabled = group.entries.filter(entry => not entry.disabled)
        match enabled.at(lastItem ? enabled.length - 1 : 0)
          case some(entry)
            focus(id + "-" + group.id + "-item-" + entry.id)
          case none
            focus(id + "-menu")
      case none
        expanded = false
  action closeMenu
    expanded = false
    match groups.at(active)
      case some(group)
        focus(id + "-" + group.id)
      case none
        expanded = false
  action toggle(index: number)
    if expanded and active == index
      closeMenu()
    else
      open(index, false)
  action pressTrigger(index: number)
    if hoverSwitched and expanded and active == index
      hoverSwitched = false
    else
      toggle(index)
  action changed(token: number, e: ToggleEvent)
    if token == opening
      expanded = e.newState == "open"
  action nextGroup(index: number, k: string)
    let next = (k == "Home" ? 0 : k == "End" ? groups.length - 1 : (index + (k == "ArrowRight" ? 1 : groups.length - 1)) % max(1, groups.length))
    if expanded
      open(next, false)
    else
      active = next
      match groups.at(next)
        case some(group)
          focus(id + "-" + group.id)
        case none
          active = 0
  action hoverTrigger(index: number, inside: bool)
    if expanded and inside and active != index
      open(index, false)
      hoverSwitched = true
  action triggerKeys(index: number, k: string)
    if k == "Enter" or k == " "
      preventDefault()
      toggle(index)
    else if k == "ArrowLeft" or k == "ArrowRight" or k == "Home" or k == "End"
      preventDefault()
      nextGroup(index, k)
    else if k == "ArrowDown" or k == "ArrowUp"
      preventDefault()
      open(index, k == "ArrowUp")
    else if k == "Escape"
      closeMenu()
  action pick(entry: MenuEntry)
    if not entry.disabled
      closeMenu()
      choose(entry.id)
  action itemKeys(groupIndex: number, entryId: string, k: string, e: KeyboardEvent)
    if not e.isComposing
      if k == "Enter" or k == " "
        preventDefault()
        match groups.at(groupIndex)
          case some(group)
            match first(group.entries.filter(entry => entry.id == entryId and not entry.disabled))
              case some(entry)
                pick(entry)
              case none
                stopPropagation()
          case none
            stopPropagation()
      else if k == "ArrowLeft" or k == "ArrowRight"
        preventDefault()
        nextGroup(groupIndex, k)
      else
        match groups.at(groupIndex)
          case some(group)
            let enabled = group.entries.filter(entry => not entry.disabled)
            let index = enabled.map(entry => entry.id).indexOf(entryId)
            if k == "ArrowDown" or k == "ArrowUp" or k == "Home" or k == "End"
              preventDefault()
              let next = (k == "Home" ? 0 : k == "End" ? enabled.length - 1 : (index + (k == "ArrowDown" ? 1 : enabled.length - 1)) % max(1, enabled.length))
              match enabled.at(next)
                case some(entry)
                  focus(id + "-" + group.id + "-item-" + entry.id)
                case none
                  closeMenu()
            else if k.length == 1 and k != " " and not e.ctrlKey and not e.metaKey and not e.altKey
              let ordered = enabled.slice(index + 1).concat(enabled.slice(0, index + 1))
              match first(ordered.filter(entry => entry.label.toLowerCase().startsWith(k.toLowerCase())))
                case some(entry)
                  preventDefault()
                  focus(id + "-" + group.id + "-item-" + entry.id)
                case none
                  stopPropagation()
          case none
            closeMenu()
  view
    row id=id testId=id position="relative" resize=resized role="menubar" aria-label="Menu de l’application" gap="ui.space-4" align-items="center" flex-wrap="wrap"
      padding="ui.space-4" border-width="ui.border-width" border-style="solid" border-color="ui.border" border-radius="ui.radius-menu" background-color="ui.surface" min-height="ui.space-36" box-sizing="border-box"
      view id=(id + "-anchor") aria-hidden=true pointer-events="none" position="absolute" left=anchorX top=anchorY width=anchorWidth height=anchorHeight margin-top="calc(0px - ui.border-width)" margin-left="calc(0px - ui.border-width)"
      for group, i in groups key=group.id
        column align-items="flex-start"
          button id=(id + "-" + group.id) testId=(id + "-" + group.id) class=Control font-weight=uiWeights.medium role="menuitem"
            tabindex=(active == i ? 0 : -1) aria-haspopup="menu" aria-expanded=(expanded and active == i) aria-controls=(id + "-menu") popovertarget=(expanded ? id + "-menu" : "") popovertargetaction="show"
            press=pressTrigger(i) hover=hoverTrigger(i) key=triggerKeys(i) padding="ui.space-4 ui.space-8" min-height="ui.space-28" border="0" border-radius="ui.radius-sm" background-color=(expanded and active == i ? "ui.muted" : "transparent") color="ui.foreground" font-size="ui.text-sm"
            text group.label font-family=uiFontFamily(uiFont) data-rightui-font="body"
      if expanded
        for token in [opening] key=token
          DropdownMenuPanel(id=prefix, panelId=id + "-menu", switching=switching, label=currentLabel, entries=current, bar=true, firstGroup=(active == 0), centered=false, circular=false, separateDestructive=false, reduced=reduced, changed=changed(token), closeMenu=closeMenu, pick=pick, itemKeys=itemKeys(active))

```
